[SOLVED] Xiaomi wireless switch + lamp basic definitions

Setup, Configuration and Use Scripts & Rules
, ,
1

Hello world,
I am very new to OpenHAB. currently using my windows10 laptop to test it, but soon the RPi will come.

I am trying to program my button to toggle the lamp On/Off.

FirstTry.rules:

rule "Toggle Celing Lamp"
when
    ButtonTest.state changed
then
    if (BP01.state == ON)
    {
        if (LivingRoom_LightCeil.state == ON)
        {
            LivingRoom_LightCeil.sendCommand(OFF)
        }
        if (ButtonTest.state == OFF)
        {
            LivingRoom_LightCeil.sendCommand(ON)
        }
    }
end

default.items:

Switch    LivingRoom_LightCeil  "Luster"          <light>         (LivingRoom, gLight)      ["Lighting"]     {channel="miio:generic:04572C43:power"}  
Switch    ButtonTest            "Pokusny vypinac" <wallswitch>    (LivingRoom, gSwitch)                      {channel="mihome:sensor_switch:158d000201706b:button"}

both - button and celing light are paired through paperui and in events.log i can see, that both are working.

anyway, nothing happened and the events.log is showing only this:

2018-09-22 13:44:41.531 [vent.ChannelTriggeredEvent] - mihome:sensor_switch:158d000201706b:button triggered SHORT_PRESSED

I am using latest OH for windows. What i am doing wrong?

Thank you for answers,
Michal, Slovakia

2

Change the above bit to:

rule "Toggle Celing Lamp" 

when

       Item ButtonTest changed
then
3

Should be: Item ButtonTest changed from OFF to ON

4

But it’s a toggle button so a press just needs the lamp to change to the state which it currently isn’t, irrespective of whether the current state is ON or OFF so the ‘from OFF to ON’ is neither needed or desirable.

5

In the rule, what is the item BP01?

6

Hi,

I use the Xiaomi Aqara Smart Switch 2 Button

in my rules I don’t refer to the item but directly to the channel

i.e. My channel is mihome:86sw2:xxxxxxxxxxxxxd:ch1

rule "Lam on when I press button"

when
        Channel "mihome:86sw2:xxxxxxxxxxxxxd:ch1" triggered
then
     lampxxx.sendCommand(ON)}
end

i have not been able to get it to work with a item
Maybe someone else has experience with linking xiaomi switches with a Item

But the above example works for me

I have 3 separate switches that operate that way without problems

First try a simple rule like above and if that is working you can always extend it

7

The Xiaomi binding does not support channel triggers
You need to link the channel to an item and use that item for the trigger

8

I use the "Xiaomi Mi Smart Home Binding" on OH 2.3

Have no trouble to use the channel trigger in a rule

I prefer to use it thru a item, but I couldn’t get it to work, this was on OH 2.1

Maybe I did something wrong or it was a bug.

10

sorry, mistake. it was taken from other script, now it is replaced by “ButtonTest”

rule "Toggle Ceiling Lamp"
when
    ButtonTest.state changed
then
    if (ButtonTest.state == ON)
    {
        if (LivingRoom_LightCeil.state == ON)
        {
            LivingRoom_LightCeil.sendCommand(OFF)
        }
        if (ButtonTest.state == OFF)
        {
            LivingRoom_LightCeil.sendCommand(ON)
        }
    }
end

still nothing works


11

It doesn’t work because you did not change

 ButtonTest.state changed

to

Item ButtonTest changed
12

Like this?

rule "Toggle Ceiling Lamp"
when
    Item ButtonTest changed
then
    if (ButtonTest.state == ON)
    {
        if (LivingRoom_LightCeil.state == ON)
        {
            LivingRoom_LightCeil.sendCommand(OFF)
        }
        if (ButtonTest.state == OFF)
        {
            LivingRoom_LightCeil.sendCommand(ON)
        }
    }
end

No, does not work :confused:

13

Your logic is flawed:

rule "Toggle Ceiling Lamp"
when
    Item ButtonTest changed
then
    if (ButtonTest.state == NULL) return; //DO NOTHING IF NULL
    if (LivingRoom_LightCeil.state == NULL) return; //DO NOTHING IF NULL
        if (LivingRoom_LightCeil.state == OFF) {
            LivingRoom_LightCeil.sendCommand(ON)
        }
        else {
            LivingRoom_LightCeil.sendCommand(OFF)
        }
end
14

so back to the basics


how would the simple ON command looks like?

when I switched on the Ceiling lamp manually through PaperUI, log is like this:

Item 'LivingRoom_LightCeil' received command ON
LivingRoom_LightCeil changed from OFF to ON

EDIT:
This works:

rule "toggle"
when
    Channel "mihome:sensor_switch:158d000201706b:button" triggered
then
    var actionName = receivedEvent.getEvent()
    switch(actionName) {
        case "SHORT_PRESSED": {
            LivingRoom_LightCeil.sendCommand(ON)
        }
        case "DOUBLE_PRESSED": {
            LivingRoom_LightCeil.sendCommand(OFF)
        }
    }
end

Now how to toggle SHORT_PRESS to ON and OFF?

15 
rule "toggle"
when
    Channel "mihome:sensor_switch:158d000201706b:button" triggered
then
    var actionName = receivedEvent.getEvent()
    switch(actionName) {
        case "SHORT_PRESSED": {
            if (LivingRoom_LightCeil.state == OFF) {
                LivingRoom_LightCeil.sendCommand(ON)
            }
            else {
                LivingRoom_LightCeil.sendCommand(OFF)
            }
        }
        case "DOUBLE_PRESSED": {
            LivingRoom_LightCeil.sendCommand(OFF)
        }
    }
end
1 Like
16

Woooow, works, thank you very much, Vincent!!!

17

Please mark the thread as solved, thank you